FC-3005 allow DSN and configs to be set by environment variables

Author: justincarter

Application.cfc

@@ -34,6 +34,66 @@
 	<cfinclude template="#this.projectConstructorLocation#" />
 
 
+	<!--- set up the farcry dsn from the environment --->
+	<cfif structKeyExists(THIS, "bUseEnv") AND THIS.bUseEnv eq "true">
+		<cfset system = createObject("java", "java.lang.System")>
+		<cfset FARCRY_DSN = "" & system.getEnv("FARCRY_DSN")>
+
+		<cfif len(FARCRY_DSN)>
+
+			<!--- set the farcry dsn, dbtype and dbowner --->
+			<cfset THIS.dsn = FARCRY_DSN /> 
+			<cfset FARCRY_DBTYPE = system.getEnv("FARCRY_DBTYPE")>
+			<cfif NOT isNull(FARCRY_DBTYPE)>
+				<cfset THIS.dbType = FARCRY_DBTYPE>
+			</cfif>
+			<cfset FARCRY_DBOWNER = system.getEnv("FARCRY_DBOWNER")>
+			<cfif NOT isNull(FARCRY_DBOWNER)>
+				<cfset THIS.dbOwner = FARCRY_DBOWNER>
+			</cfif>
+
+			<!--- set up the datasource settings --->
+			<cfset this.datasources[FARCRY_DSN] = {
+				"class" = system.getEnv("FARCRY_DSN_CLASS"),
+				"connectionString" = system.getEnv("FARCRY_DSN_CONNECTIONSTRING"),
+				"database" = system.getEnv("FARCRY_DSN_DATABASE"),
+				"driver" = system.getEnv("FARCRY_DSN_DRIVER"),
+				"host" = system.getEnv("FARCRY_DSN_HOST"),
+				"port" = system.getEnv("FARCRY_DSN_PORT"),
+				"type" = system.getEnv("FARCRY_DSN_TYPE"),
+				"url" = system.getEnv("FARCRY_DSN_URL"),
+				"username" = system.getEnv("FARCRY_DSN_USERNAME"),
+				"password" = system.getEnv("FARCRY_DSN_PASSWORD")
+			}>
+
+			<!--- set custom options when not using a connection string --->
+			<cfset FARCRY_DSN_CUSTOM = system.getEnv("FARCRY_DSN_CUSTOM")>
+			<cfif NOT isNull(FARCRY_DSN_CUSTOM) AND len(FARCRY_DSN_CUSTOM)>
+				<cfif isJSON(FARCRY_DSN_CUSTOM)>
+					<cfset this.datasources[FARCRY_DSN].custom = deserializeJSON(FARCRY_DSN_CUSTOM)>
+				<cfelse>
+					<cfset stCustom = {}>
+					<cfloop list="#FARCRY_DSN_CUSTOM#" index="item" delimiters="&">
+						<cfset stCustom[listFirst(item, "=")] = listRest(item, "=")>
+					</cfloop>
+					<cfset this.datasources[FARCRY_DSN].custom = stCustom>
+				</cfif>
+			</cfif>
+
+			<!--- set linked db hostname/port using the provided alias --->
+			<cfset FARCRY_DB_LINK_ALIAS = system.getEnv("FARCRY_DB_LINK_ALIAS")>
+			<cfif NOT isNull(FARCRY_DB_LINK_ALIAS) AND len(FARCRY_DB_LINK_ALIAS)>
+				<cfset DB_PORT = system.getEnv(ucase(FARCRY_DB_LINK_ALIAS) & "_PORT")>
+				<cfif NOT isNull(DB_PORT) AND len(DB_PORT)>
+					<cfset this.datasources[FARCRY_DSN].host = listFirst(listLast(DB_PORT, "/"), ":")>
+					<cfset this.datasources[FARCRY_DSN].port = listLast(listLast(DB_PORT, "/"), ":")>
+				</cfif>
+			</cfif>
+
+		</cfif>
+	</cfif>
+
+
 	<cfparam name="this.botDetection" default="true" />
 	<cfif this.botDetection>
 		<!--- Bot detection values --->
@@ -745,6 +805,9 @@
 		<cfparam name="this.bUseMobileWebskins" default="false" /><!--- Mobile webskins are enabled when this flag is set to true --->
 		<cfparam name="this.bUseTabletWebskins" default="false" /><!--- Tablet webskins are enabled when this flag is set to true --->
 
+		<!--- environment configuration --->
+		<cfparam name="this.bUseEnv" default="false" />
+
 		<!--- Option to archive --->
 		<cfparam name="this.bUseMediaArchive" default="false" />
 

tags/farcry/_farcryApplicationInit.cfm

@@ -143,6 +143,22 @@ test for the existance of each and act accordingly
 </cfloop>
 <cfset application.fc.lib.db.setLogChangeFlags(application.config.general.logDBChanges) />
 
+<!--- set up the configs from the environment --->
+<cfif structKeyExists(THIS, "bUseEnv") AND THIS.bUseEnv eq "true">
+	<cfset system = createobject("java", "java.lang.System")>
+	<cfset ENV = system.getEnv()>
+	<cfset ENV_ARRAY = ENV.keySet().toArray()>
+	<cfloop from="1" to="#arrayLen(ENV_ARRAY)#" index="i">
+		<cfif findNoCase("FARCRY_CONFIG_", ENV_ARRAY[i]) AND listLen(ENV_ARRAY[i], "_") gte 4>
+			<cfset configKey = listGetAt(ENV_ARRAY[i], 3, "_")>
+			<cfset configProperty = replaceNoCase(ENV_ARRAY[i], "FARCRY_CONFIG_#configKey#_" , "")>
+			<cfset configValue = ENV.get(ENV_ARRAY[i])>
+			<cfset application.fapi.setConfig(configKey, configProperty, configValue, true)>
+		</cfif>
+	</cfloop>
+</cfif>
+
+
 <!--- wrap this in a cftry catch in case the policystore isn't initialised yet  --->
 <!--- <cfif StructKeyExists(request,"init") AND request.init eq 0> --->