Qn: possible to get the type of a sub object in query

[anisjonischkeit]

Say I have the following query:

module GetUser = [%graphql
  {|
    {
        users @bsRecord {
          first_name
          last_name
          email
          company {
            name 
          }
        }
      }
   |}
];

Is it possible to get the type of company?

[anisjonischkeit]

I guess I'm probably looking for a directive (like @genType) on company to tell the ppx to generate the type.

[baransu]

Right now the whole response is just one big object. There is no way to get the type of the part of the response, unfortunately.

[anisjonischkeit]

ahh lameeee! Well I've been curious about what writing ppxs is like anyway so I might give adding something a go over the next couple of weeks 😄

[maarekj]

It's possible:

module Meta = {
  module type mt_ret = {type t;};
  type typed_ret('a) = (module mt_ret with type t = 'a);
  let ret_type = (type a, _: _ => a): typed_ret(a) => {
    module MT_Ret = {
      type t = a;
    };
    (module MT_Ret);
  };
};

module GetUser = [%graphql
  {|
    {
        users @bsRecord {
          first_name
          last_name
          email
          company {
            name 
          }
        }
      }
   |}
];

/** this code will never be executed. It is used only by the compiler to retrieve the type of return */
module MT_Ret = (val Meta.ret_type((json) => GetUser.parse(json)##users[0]##company));
type company = MT_Ret.t;

[anisjonischkeit]

Very clever! This looks useful in lots of other places too.