dev-python/librosa: new package

dev-python/librosa/librosa-9999.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 git-r3
+
+DESCRIPTION="Python library for audio and music analysis"
+HOMEPAGE="https://github.com/librosa/librosa"
+EGIT_REPO_URI="$HOMEPAGE"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/numpy-1.22.2[${PYTHON_USEDEP}]
+	>=dev-python/audioread-2.1.9[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/scikit-learn-0.20.0[${PYTHON_USEDEP}]
+	>=dev-python/joblib-0.14[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.3.0[${PYTHON_USEDEP}]
+	>=dev-python/numba-0.51.0[${PYTHON_USEDEP}]
+	>=dev-python/soundfile-0.12.1[${PYTHON_USEDEP}]
+	>=dev-python/pooch-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/soxr-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.1.1[${PYTHON_USEDEP}]
+	>=dev-python/lazy-loader-0.1[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-mpl[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:--cov[a-z-]*\(=\| \)[a-z-]*::g' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		#Network
+		'tests/test_util.py::test_example'
+		'tests/test_util.py::test_cite_badversion'
+		'tests/test_util.py::test_cite_unreleased'
+		'tests/test_util.py::test_cite_released'
+		'tests/test_core.py::test_load'
+
+		#Missing test dependencies(resampy, samplerate)
+		'tests/test_core.py::test_resample_mono'
+		'tests/test_core.py::test_resample_scale'
+		'tests/test_core.py::test_resample_stereo'
+		'tests/test_multichannel.py::test_resample_multichannel'
+		'tests/test_multichannel.py::test_resample_highdim_axis'
+		'tests/test_multichannel.py::test_resample_highdim'
+	)
+
+	epytest -p pytest_mpl
+}

dev-python/mir_eval/Manifest

@@ -0,0 +1 @@
+DIST mir_eval-0.8.0_rc1.gh.tar.gz 2602154 BLAKE2B 0ea79ed98de45a48bb2baaeb85b30558eeeffab190b843288f90b8cb5dd18bcb7bf623d002f6b85384e44bdbc1a12b13b47bb3ec24bcfbc5f4e07b64c274a434 SHA512 4f7eb2221332244a8cdedcbb4667b619b1464303bbff04040d3be99b47ad880b7ccfabd6d008c91de9a7ca550dc46dfd010462f81913b128edf544ae7b9b9d29

dev-python/mir_eval/mir_eval-0.8.0_rc1.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+DOCS_BUILDER="sphinx"
+DOCS_DEPEND="
+	dev-python/numpydoc
+	dev-python/sphinx-rtd-theme
+	dev-python/matplotlib
+"
+DOCS_DIR="docs"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="Evaluation functions for music/audio information retrieval/signal processing"
+HOMEPAGE="https://github.com/mir-evaluation/mir_eval"
+SRC_URI="
+	https://github.com/mir-evaluation/mir_eval/archive/${PV/_rc/rc}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${P/_rc/rc}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/numpy
+	dev-python/scipy
+	dev-python/decorator
+"
+BDEPEND="
+	test? (
+		dev-python/matplotlib
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:--cov[a-z-]*\(=\| \)[^ ]*.::g' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	cd "tests" || die
+	epytest
+}

dev-python/presets/Manifest

@@ -0,0 +1 @@
+DIST presets-1.0.0.gh.tar.gz 12319 BLAKE2B d6395229f510983d193cd4c54db84d8f2392d36b602f64e18e01e7afed9fd9f43dda1e952c3bff1262d227015e3151e36b3e1d53de2efd0a8115577b4fc26861 SHA512 dc531757af6db58967974a582d273107c4a3da28b5c433f1e0cf78a0417a073471c4cac15b5cd8a057674c3767616bddf5ec39f3bd40a6613e8e60bc9bf020df

dev-python/presets/presets-1.0.0.ebuild

@@ -0,0 +1,31 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+DOCS_BUILDER="sphinx"
+DOCS_DEPEND="dev-python/numpydoc"
+DOCS_DIR="docs"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="A python module to manipulate default parameters of a module's functions"
+HOMEPAGE="https://github.com/bmcfee/presets"
+SRC_URI="
+	https://github.com/bmcfee/presets/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:--cov[a-z-]*\(=\| \)[^ ]*.::g' setup.cfg || die
+	distutils-r1_src_prepare
+}

dev-python/soxr/Manifest

@@ -0,0 +1 @@
+DIST soxr-0.5.0.gh.tar.gz 27175 BLAKE2B cfce267286208829e1bd2a7f990de55d931f241e81702dfa3be23fbce53b9d710a0eb75d7c0b7f7b419ea01015a0d96f520f2e2da4baee82676cbc04f73b76ad SHA512 43e4dac1cc6da24f39edcf896604077ff7863f3fcc29d08118f4f184992d0c0bfc089e0139bb8f7dd5dba4c0de95dc2c6930907c69aafcde6f9b62a63b0cf12c

dev-python/soxr/soxr-0.5.0.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=scikit-build-core
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+DOCS_BUILDER="sphinx"
+DOCS_DEPEND="
+	dev-python/linkify-it-py
+	dev-python/sphinx-rtd-theme
+	dev-python/myst-parser
+"
+DOCS_DIR="docs"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="Fast and high quality sample-rate conversion library for Python"
+HOMEPAGE="https://github.com/dofuuz/python-soxr/"
+SRC_URI="
+	https://github.com/dofuuz/python-soxr/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/python-soxr-${PV}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	media-libs/soxr
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	dev-python/nanobind[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	sed -i 's:sphinx-book-theme:sphinx-rtd-theme:g' pyproject.toml || die
+	sed -i 's:sphinx_book_theme:sphinx_rtd_theme:g' docs/conf.py || die
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	DISTUTILS_ARGS=(
+		-DUSE_SYSTEM_LIBSOXR=ON
+	)
+}

dev-python/sphinxcontrib-svg2pdfconverter/Manifest

@@ -0,0 +1 @@
+DIST sphinxcontrib-svg2pdfconverter-1.2.3.gh.tar.gz 5554 BLAKE2B d358c781779c5a4e14c780a291c860c3f995b9a82085b4d9db237722dadcb3cb43e87ac55ff82a8d12e746fbdd0823244bccd2bc524bad37746e8c6bcc717963 SHA512 cec6c8ce0c15cae9f76f6ccecffebe6b8d55199a1887b63a34bc8607f0e47332cbc31939acce2d0d268d69054495788e4ad457e58216e10dfba1e427a2edbee7

dev-python/sphinxcontrib-svg2pdfconverter/metadata.xml

@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<use>
+		<flag name="cairosvg">Depend on cairosvg as main backend</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">missinglinkelectronics/sphinxcontrib-svg2pdfconverter</remote-id>
+	</upstream>
+</pkgmetadata>

dev-python/sphinxcontrib-svg2pdfconverter/sphinxcontrib-svg2pdfconverter-1.2.3.ebuild

@@ -0,0 +1,26 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Sphinx SVG to PDF converter extension"
+HOMEPAGE="https://github.com/missinglinkelectronics/sphinxcontrib-svg2pdfconverter"
+SRC_URI="
+	https://github.com/missinglinkelectronics/sphinxcontrib-svg2pdfconverter/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="cairosvg"
+
+RDEPEND="
+	cairosvg? ( media-gfx/cairosvg )
+	!cairosvg? ( gnome-base/librsvg )
+"